# delimit;
set more 1;
set memory 80m;

* increase maximum variables;
set matsize 200;

*define log;
log using michigan.log,replace;

*read in stata data file;
use michigan;

* construct new variables;
gen mi=state==26;    * michigan dummy;
gen hike=month>=33;  * treatment period dummy;
gen treatment=hike*mi;  * treatment dummy variable;
label var mi "michigan dummy variable";
label var hike "time period after tax hike";
label var treatment "=1 if in in after tax hike";

* get means of smoking rates for the 2xs box;
sort mi hike;
by mi hike: sum smoked;

* now run the regression;
reg smoked mi hike treatment;

* now control for observed characteristics;
* generate dummy variables to control for race, parity, education and age;
xi i.age i.mrace3 i.meduc6 i.ageg;

* add these variables to the model;
reg smoked mi hike treatment _I*;


* now control for all time periods and all states;
* need to define time and state dummies;
* in the regression, drop the mi and hike variables;
xi i.age i.mrace3 i.meduc6 i.ageg i.state i.month;
reg smoked treatment _I*;

clear;
log close;