* Problem 2.  Quality of Employment survey. Modify file name
* and location if necessary.
Get FILE="D:\soc63993\homework\jgqes2.sav"
   / keep = prof mang race hrswk tenure firmsize jsat.


* Compute "Good job" variable (professional or managerial).
COMPUTE GDJOB=PROF+MANG.
* Compute dummy variable for white/ nonwhite.
RECODE race (1=1) (else=0) into white.
* hrswk (hours work per week) seems to be off by factor of 10,
* so correct.
Compute hrswk = hrswk/10.
value labels gdjob 0 'Other' 1 'Prof, Manager'/
             white 0 'Nonwhite' 1 'White'.

* Compute race interaction terms.
COMPUTE tenurewh=TENURE*white.
COMPUTE firmszwh=FIRMSIZE*white.
COMPUTE gdjobwh=GDJOB*white.
COMPUTE hrswkwh=HRSWK*white.

* Regressions, set 1. Mean job satisfaction difference between groups.
REGRESSION /VARIABLES=JSAT white GDJOB gdjobwh TENURE tenurewh
                      FIRMSIZE firmszwh HRSWK hrswkwh
           /statistics cha def
           /DEPENDENT JSAT
           /METHOD ENTER white.

* Regressions, set 2.  Test for any differences between groups.
REGRESSION /VARIABLES=JSAT white GDJOB gdjobwh TENURE tenurewh
                      FIRMSIZE firmszwh HRSWK hrswkwh
           /statistics cha def
           /DEPENDENT JSAT
           /METHOD ENTER GDJOB tenure firmsize hrswk
           /method enter white gdjobwh tenurewh firmszwh hrswkwh.

* Regressions, set 3. Test for interaction effects.
REGRESSION /VARIABLES=JSAT white GDJOB gdjobwh TENURE tenurewh
                      FIRMSIZE firmszwh HRSWK hrswkwh
           /statistics cha def
           /DEPENDENT JSAT
           /method enter gdjob tenure firmsize hrswk white
           /method enter gdjobwh tenurewh firmszwh hrswkwh.

T-TEST
  GROUPS=white(0 1)
  /MISSING=ANALYSIS
  /VARIABLES=gdjob tenure firmsize hrswk
  /CRITERIA=CIN(.95) .